extends Node2D
@onready var game: GameController = $".."
@onready var crates: Node2D = $"../Crates"
@onready var player: Player = $"../Player"

var bullet = preload("res://scenes/bullet.tscn")
var bulletArray:Array[Bullet] = []
var totalAllowedBullet:int = 7

# Called when the node enters the scene tree for the first time.
func _ready() -> void:
	# signals from the view
	player.pushSignal.connect(pushTarget)
	player.shootSignal.connect(makeBullet)
	# signals from the game controller
	game.destroySignal.connect(destroy)
	game.fanTriggerSignal.connect(pushTarget)
	game.teleportTriggerSignal.connect(teleportTarget)
	buildLevel()

# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(delta: float) -> void:
	pass

func buildLevel() -> void:
	updateCrates()

func updateCrates() -> void:
	var totalCrates = 0
	if crates:
		for obj in crates.get_children():
			if obj is Crate:
				if not obj.tree_exited.is_connected(updateCrates):
					obj.tree_exited.connect(updateCrates)
				totalCrates += 1
	game.crateTotal(totalCrates)

func pushTarget(body,pushDirection) -> void:
	if body is RigidBody2D:
		body.apply_central_impulse(pushDirection)
		
func destroy(body) -> void:
	body.queue_free()

func teleportTarget(body) -> void:
	if body is Crate:
		var viewport_size = get_viewport().get_visible_rect().size
		var random_x = randf_range(0,viewport_size.x)
		var random_y = randf_range(0,viewport_size.y)
		var newPosition = Vector2(random_x, random_y)
		body.teleport_to(newPosition)
		
func bulletFactory() -> Bullet:
	var myBullet:Bullet
	if bulletArray.size() <= totalAllowedBullet:
		myBullet = bullet.instantiate()
		add_sibling(myBullet)
		if not myBullet.bulletHitSignal.is_connected(game.bulletDamage):
			myBullet.bulletHitSignal.connect(game.bulletDamage)
	else:
		myBullet = bulletArray.pop_back()
	bulletArray.push_front(myBullet)
	return myBullet

func makeBullet(spawnPosition, speed) -> void:
	print("make bullet")
	var myBullet:Bullet = bulletFactory()
	myBullet.transform = spawnPosition
	myBullet.setSpeed(speed)