class_name Player extends CharacterBody2D
@onready var right_cast: RayCast2D = $RightCast
@onready var left_cast: RayCast2D = $LeftCast
@onready var right_spawn: Marker2D = $RightSpawn
@onready var left_spawn: Marker2D = $LeftSpawn
@onready var player_graphic: AnimatedSprite2D = $PlayerGraphic


const SPEED = 300.0
const JUMP_VELOCITY = -400.0
var direction
enum FaceDirection{LEFT,RIGHT}
var facing:FaceDirection = FaceDirection.RIGHT
enum PlayerState{IDLE,RUNNING}
var current_player_state:PlayerState = PlayerState.IDLE

var pushTarget:RigidBody2D
var pushEnabled:bool = false

func _physics_process(delta: float) -> void:
	handle_input()
	handle_movement(delta)
	handle_state()
	handle_animation()
	move_and_slide()
	handle_collisions()
			
func handle_input()->void:
	if Input.is_action_just_pressed("chuck"):
		print("Chuck a grenade")
		%SceneManager.makeGrenade(right_spawn.global_transform, 1)
		
	if Input.is_action_just_pressed("shove") and pushEnabled:
		print("Shove somethin")
		# determine what direction to shove the thing
		var shoveDirection:int
		match facing:
			FaceDirection.RIGHT:
				shoveDirection = 1
			FaceDirection.LEFT:
				shoveDirection = -1
		pushTarget.apply_central_impulse(Vector2(shoveDirection,0)*700)
		
	if Input.is_action_just_pressed("jump") and is_on_floor():
		velocity.y = JUMP_VELOCITY

	# Get the input direction and handle the movement/deceleration.
	# As good practice, you should replace UI actions with custom gameplay actions.
	direction = Input.get_axis("left", "right")
	if direction<0:
		facing = FaceDirection.LEFT
		player_graphic.flip_h = true
	if direction>0:
		facing = FaceDirection.RIGHT
		player_graphic.flip_h = false
	
func handle_movement(delta)->void:
	# Add the gravity.
	if not is_on_floor():
		velocity += get_gravity() * delta
	# Handle jump.
	
	if direction:
		velocity.x = direction * SPEED
	else:
		velocity.x = move_toward(velocity.x, 0, SPEED)
		
func handle_collisions()->void:
	if right_cast.is_colliding() and facing==FaceDirection.RIGHT:
		print("Right raycast contact!!")
		pushEnabled = true
		var collider = right_cast.get_collider()
		pushTarget = collider
		
	if left_cast.is_colliding() and facing==FaceDirection.LEFT:
		print("Left raycast contact!!")
		pushEnabled = true
		var collider = left_cast.get_collider()
		pushTarget = collider
		
	if not right_cast.is_colliding() and not left_cast.is_colliding():
		pushEnabled = false
		
	for i in get_slide_collision_count():
		var c = get_slide_collision(i)
		if c.get_collider() is RigidBody2D:
			#deliver the impact
			if not c.get_collider() is Grenade:
				c.get_collider().apply_central_impulse(-c.get_normal() * 100)

func handle_state()->void:
	match current_player_state:
		PlayerState.IDLE when velocity.x !=0:
			#change to running
			current_player_state = PlayerState.RUNNING
		PlayerState.RUNNING when velocity.x ==0:
			current_player_state = PlayerState.IDLE
			
func handle_animation()->void:
	match current_player_state:
		PlayerState.IDLE:
			player_graphic.play("idle")
		PlayerState.RUNNING:
			player_graphic.play("run")