extends Node2D
@onready var game: GameController = $".."
@onready var crates: Node2D = $"../Crates"
@onready var player: Player = $"../Player"
@onready var coin: Coin = $"../Coins/Coin"
@onready var coins: Node2D = $"../Coins"
@onready var enemies: Node2D = $"../Enemies"

var bullet = preload("res://scenes/bullet.tscn")
var rocket = preload("res://scenes/rocket.tscn")

var bulletArray:Array[Bullet] = []
var totalAllowedBullets:int = 7
var rocketDict:Dictionary = {}
var totalAllowedRockets:int = 3

# Called when the node enters the scene tree for the first time.
func _ready() -> void:
	#signals from the view
	player.pushSignal.connect(pushTarget)
	player.shootSignal.connect(makeBullet)
	player.fireSignal.connect(makeRocket)
	player.deathAnimationCompleteSignal.connect(game.loadLevel)
	
	#signals from the GameController
	game.destroySignal.connect(destroy)
	game.fanTriggerSignal.connect(pushTarget)
	game.teleportTriggerSignal.connect(teleportTarget)
	game.playerDamagedSignal.connect(player.hurt)
	game.playerDeathSignal.connect(player.kill)
	
	#signals from pickups
	coin.coinCollectedSignal.connect(game.coinCollected)
	buildLevel()


# Called every frame. 'delta' is the elapsed time since the previous frame.
func _process(delta: float) -> void:
	pass

func buildLevel()->void:
	#tell GC how many crates...
	updateCrates()
	updateCoins()
	updateEnemies()

func updateEnemies()->void:
	if enemies:
		for obj in enemies.get_children():
			if obj is Slime:
				game.addEnemyToLevel(obj)
				#hook up to game controller
				if not obj.slimeDamageSignal.is_connected(game._on_slime_damage):
					obj.slimeDamageSignal.connect(game._on_slime_damage)
					
func updateCrates()->void:
	var totalCrates = 0
	if crates:
		for obj in crates.get_children():
			if obj is Crate:
				if not obj.tree_exited.is_connected(updateCrates):
					obj.tree_exited.connect(updateCrates)
				totalCrates +=1
	
	game.crateTotal(totalCrates)

#any time a coin exits tree, game controller is updated
func updateCoins()->void:
	var totalCoins = 0
	if coins:
		for obj in coins.get_children():
			if obj is Coin:
				if not obj.coinCollectedSignal.is_connected(game.coinCollected):
					obj.coinCollectedSignal.connect(game.coinCollected)
				if not obj.tree_exited.is_connected(updateCoins):
					obj.tree_exited.connect(updateCoins)
				totalCoins +=1
	game.coinTotal(totalCoins)
	
func pushTarget(body,pushDirection)->void:
	if body is RigidBody2D:
		body.apply_central_impulse(pushDirection)
func stashBullet(bullet:Bullet)->void:
	#hide the bullet
	var stashPosition:Vector2 = Vector2(-100,-100)
	bullet.position = stashPosition
	bullet.setSpeed(0)
	bullet.set_process(false)
	
func destroy(body)->void:
	match body:
		var bod when bod is Bullet:
			stashBullet(body)
		var bod when bod is Crate:
			body.queue_free()
		_:
			body.queue_free()
	
func teleportTarget(body)->void:
	if body is Crate:
		var viewport_size = get_viewport().get_visible_rect().size
		var random_x = randf_range(0, viewport_size.x)
		var random_y = randf_range(0, viewport_size.y)
		var newPosition = Vector2(random_x,random_y)
		body.teleport_to(newPosition)
func bulletFactory()->Bullet:
	var myBullet:Bullet
	#how many bullets have been produced?
	if bulletArray.size() <= totalAllowedBullets:
		#make a new bullet
		myBullet = bullet.instantiate()
		add_sibling(myBullet)
		if not myBullet.bulletHitSignal.is_connected(game.bulletDamage):
			myBullet.bulletHitSignal.connect(game.bulletDamage)
	else:
		myBullet = bulletArray.pop_back()
		
	bulletArray.push_front(myBullet)
	return myBullet
func makeBullet(spawnPosition, speed)->void:
	print("make bullet")
	var myBullet:Bullet = bulletFactory()
	myBullet.transform = spawnPosition
	myBullet.setSpeed(speed)
	myBullet.set_process(true)

func rocketFactory()->Rocket:
	var myRocket:Rocket
	myRocket = rocket.instantiate()
	add_sibling(myRocket)
	var rocketStat={
		"damage": 10
	}
	rocketDict[myRocket]=rocketStat
	return myRocket
	
func makeRocket(spawnPosition, direction, speed)->void:
	print("make a rocket")
	var myRocket:Rocket = rocketFactory()
	myRocket.splodeSignal.connect(destroy)
	myRocket.impactSignal.connect(game.rocketDamage)
	myRocket.transform = spawnPosition
	pushTarget(myRocket,direction*speed)