class_name Player extends CharacterBody2D
signal pushSignal(body, direction)
signal shootSignal(markerPosition, speed)
signal fireSignal(markerPosition, direction, speed)
@onready var right_cast: RayCast2D = $RightCast
@onready var left_cast: RayCast2D = $LeftCast
@onready var right_spawn: Marker2D = $RightSpawn
@onready var left_spawn: Marker2D = $LeftSpawn
@onready var player_graphic: AnimatedSprite2D = $PlayerGraphic

var pushRightEnabled = false
var pushLeftEnabled = false
var pushTarget
var pushTimer = 0

const SPEED = 300.0
const JUMP_VELOCITY = -400.0

enum FaceDirection {RIGHT,LEFT}
var facing:FaceDirection = FaceDirection.RIGHT
#State Handling
enum PlayerState {IDLE, RUNNING, JUMPING, FALLING}
var current_player_state:PlayerState = PlayerState.IDLE
var upJump:bool = false

func _physics_process(delta: float) -> void:
	
	handle_input()
	handle_movement(delta)
	#States and Animation
	handle_update_states()
	handle_update_animation()
	move_and_slide()
	handle_collisions()
	
	
func handle_input()->void:
	# Handle jump.
	if Input.is_action_just_pressed("ui_accept") and is_on_floor():
		velocity.y = JUMP_VELOCITY
		current_player_state = PlayerState.JUMPING
		upJump = true
	# Handle shove.
	if Input.is_action_just_pressed("shove"):
		print("I want to shove")
		pushTimer = Time.get_ticks_msec()
	if Input.is_action_just_released("shove"):
		var pushForce = Time.get_ticks_msec() - pushTimer
		if pushForce>4000:
			pushForce=4000
		if pushRightEnabled and facing==FaceDirection.RIGHT:
			#deliver the boom
			pushSignal.emit(pushTarget, Vector2(1,0)*100*(pushForce/100))
		if pushLeftEnabled and facing==FaceDirection.LEFT:
			pushSignal.emit(pushTarget, Vector2(-1,0)*100*(pushForce/100))
	#Handle Shoot Bullet
	if Input.is_action_just_pressed("shoot"):
		print("Ima shoot a bullet")
		#marker postion, speed
		match facing:
			FaceDirection.RIGHT:
				shootSignal.emit(right_spawn.global_transform, 800)
			FaceDirection.LEFT:
				shootSignal.emit(left_spawn.global_transform, -800)
	#Handle fire rocket
	if Input.is_action_just_pressed("fire"):
		print("Ima fire rocket")
		match facing:
			FaceDirection.RIGHT:
				fireSignal.emit(right_spawn.global_transform,Vector2(1,0), 800)
			FaceDirection.LEFT:
				fireSignal.emit(left_spawn.global_transform,Vector2(1,0), 800)	
	# Get the input direction and handle the movement/deceleration.
	# As good practice, you should replace UI actions with custom gameplay actions.
	var direction := Input.get_axis("ui_left", "ui_right")
	if direction:
		velocity.x = direction * SPEED
		if direction >0:
			facing = FaceDirection.RIGHT
			player_graphic.flip_h = false
		else:
			facing = FaceDirection.LEFT
			player_graphic.flip_h = true
	else:
		velocity.x = move_toward(velocity.x, 0, SPEED)
func handle_movement(delta)->void:
	# Add the gravity.
	if not is_on_floor():
		velocity += get_gravity() * delta		
func handle_collisions()->void:
	if right_cast.is_colliding():
		print("Right raycast collision")
		var collider = right_cast.get_collider()
		if collider is Node:
			pushRightEnabled = true
			pushTarget = collider
	else:
		pushRightEnabled = false
	
	if left_cast.is_colliding():
		print("Left raycast collision")
		var collider = left_cast.get_collider()
		if collider is Node:
			pushLeftEnabled = true
			pushTarget = collider
	else:
		pushLeftEnabled = false
		
	#a loop
	for i in get_slide_collision_count():
		var c = get_slide_collision(i)
		#is this a bonkable thing?
		if c.get_collider() is RigidBody2D:
			#c.get_collider().apply_central_impulse(-c.get_normal() * 100)
			pushSignal.emit(c.get_collider(), -c.get_normal() * 100)

#New functions for state handling
func handle_update_states()->void:
	match current_player_state:
		PlayerState.IDLE when velocity.x !=0:
			current_player_state = PlayerState.RUNNING
		PlayerState.RUNNING when velocity.x == 0:
			current_player_state = PlayerState.IDLE
		PlayerState.JUMPING when velocity.y>0:
			current_player_state = PlayerState.FALLING
		PlayerState.FALLING when is_on_floor():
			if velocity.x == 0:
				current_player_state = PlayerState.IDLE
			else:
				current_player_state = PlayerState.RUNNING
			
func handle_update_animation()->void:
	match current_player_state:
		PlayerState.IDLE:
			player_graphic.play("idle")
		PlayerState.RUNNING:
			player_graphic.play("running")
		PlayerState.JUMPING:
			if upJump:
				player_graphic.play("jumping")
		PlayerState.FALLING:
			player_graphic.play("falling")


func _on_animation_finished() -> void:
	match current_player_state:
		PlayerState.JUMPING:
			upJump = false