MarchGame/scripts/player.gd

class_name Player extends CharacterBody2D

@onready var right_target: Marker2D = $RightTarget
@onready var left_target: Marker2D = $LeftTarget
@onready var player_graphic: AnimatedSprite2D = $PlayerGraphic
@onready var right_down_cast: RayCast2D = $RightDownCast
@onready var left_down_cast: RayCast2D = $LeftDownCast


const SPEED = 300.0
const JUMP_VELOCITY = -400.0
const BUMP_POWER = 50
enum FaceDirection{LEFT, RIGHT}
var facing:FaceDirection = FaceDirection.RIGHT
var direction
#awarness
var cliffEdge = false
enum PlayerState{IDLE,RUNNING, JUMPING, FALLING}
var current_player_state:PlayerState = PlayerState.IDLE
var jumpUp:bool = false

func _ready() -> void:
	var timer = Timer.new()
	add_child(timer)
	
	timer.wait_time = 3.0  # Wait time in seconds
	timer.one_shot = false  # Set to false for repeating
	timer.autostart = true # Start automatically on enter
	timer.timeout.connect(handle_ai)
	timer.start()
	
func _physics_process(delta: float) -> void:
	
	#handle_input()
	handle_movement(delta)
	handle_state()
	handle_animation()
	move_and_slide()
	handle_collisions()

func handle_ai()->void:
	var ran = randi()%10
	#running, idle
	print("random number "+str(ran))
	direction = 0
	if ran<=4:
		direction = -1
	if ran>=7:
		direction = 1
	
	#shooting
	var shootran = randi()%5
	if shootran >3:
		shoot()
	
func jump()->void:
	if is_on_floor():
		velocity.y = JUMP_VELOCITY
		current_player_state = PlayerState.JUMPING
		jumpUp = true
func shoot()->void:
	match facing:
			FaceDirection.RIGHT:
				%SceneManager.makeBullet(right_target.global_transform, 700)
			FaceDirection.LEFT:
				%SceneManager.makeBullet(left_target.global_transform, -700)
				
func handle_input()->void:
	direction = Input.get_axis("ui_left", "ui_right")
	# Handle jump.
	if Input.is_action_just_pressed("ui_accept"):
		jump()
	# Handle Shoot
	if Input.is_action_just_pressed("shoot"):
		shoot()
func handle_state()->void:
	match current_player_state:
		PlayerState.IDLE when velocity.x !=0:
			#change to running!!
			current_player_state = PlayerState.RUNNING
		PlayerState.RUNNING when velocity.x == 0:
			current_player_state = PlayerState.IDLE
		PlayerState.JUMPING when velocity.y > 0:
			current_player_state = PlayerState.FALLING
		PlayerState.FALLING when is_on_floor():
			if velocity.x ==0:
				current_player_state = PlayerState.IDLE
			else:
				current_player_state = PlayerState.RUNNING
func handle_animation()->void:
	match current_player_state:
		PlayerState.IDLE:
			player_graphic.play("idle")	
		PlayerState.RUNNING:
			player_graphic.play("running")
		PlayerState.JUMPING:
			if jumpUp:
				player_graphic.play("jumping")
		PlayerState.FALLING:
			player_graphic.play("falling")
			
func handle_movement(delta)->void:
	
	# Add the gravity.
	if not is_on_floor():
		velocity += get_gravity() * delta
	if direction:
		velocity.x = direction * SPEED
		if direction <0:
			facing=FaceDirection.LEFT
			player_graphic.flip_h = true
		if direction >0:
			facing=FaceDirection.RIGHT
			player_graphic.flip_h = false
	else:
		velocity.x = move_toward(velocity.x, 0, SPEED)
		
func handle_collisions()->void:
	for i in get_slide_collision_count():
		var c = get_slide_collision(i)
		if c.get_collider() is RigidBody2D:
			c.get_collider().apply_central_impulse(-c.get_normal()*BUMP_POWER)
		if c.get_collider() is NPCCharacter:
			var myCharacter:NPCCharacter = c.get_collider()
			var mydirection = -c.get_normal()*BUMP_POWER
			myCharacter.knockBack(mydirection)
	if not right_down_cast.is_colliding() and is_on_floor():
		#on edge of drop on right side
		if velocity.x > 100:
			jump()
	if not left_down_cast.is_colliding() and is_on_floor():
		#on edge of drop on left side
		if velocity.x <-100:
			jump()
func _on_animation_finished() -> void:
	match current_player_state:
		PlayerState.JUMPING:
			jumpUp = false