MarchGame/scripts/player.gd

class_name Player extends CharacterBody2D

@onready var right_target: Marker2D = $RightTarget
@onready var left_target: Marker2D = $LeftTarget
@onready var player_graphic: AnimatedSprite2D = $PlayerGraphic


const SPEED = 300.0
const JUMP_VELOCITY = -400.0
const BUMP_POWER = 50
enum FaceDirection{LEFT, RIGHT}
var facing:FaceDirection = FaceDirection.RIGHT
#states for player
enum PlayerState{IDLE,RUNNING,JUMPING, FALLING}
var current_player_state:PlayerState = PlayerState.IDLE

var upJump:bool = false

func _physics_process(delta: float) -> void:
	handle_input()
	handle_movement(delta)	
	handle_update_states()
	handle_update_animation()
	move_and_slide()
	handle_collisions()

#organize the game loop
func handle_input()->void:
	# Handle Shoot
	if Input.is_action_just_pressed("shoot"):
		print("Player wants to shoot")
		match facing:
			FaceDirection.RIGHT:
				print("Shoot to the right")
				%SceneManager.makeBullet(right_target.global_transform, 700)
			FaceDirection.LEFT:
				print("Shoot to the left")
				%SceneManager.makeBullet(left_target.global_transform, -700)
		
	# Handle jump.
	if Input.is_action_just_pressed("ui_accept") and is_on_floor():
		velocity.y = JUMP_VELOCITY
		current_player_state = PlayerState.JUMPING
		upJump = true

	# Get the input direction and handle the movement/deceleration.
	# As good practice, you should replace UI actions with custom gameplay actions.
	var direction := Input.get_axis("ui_left", "ui_right")
	if direction:
		velocity.x = direction * SPEED
		if direction <0:
			facing=FaceDirection.LEFT
			player_graphic.flip_h = true
		if direction >0:
			facing=FaceDirection.RIGHT
			player_graphic.flip_h = false
	else:
		velocity.x = move_toward(velocity.x, 0, SPEED)
func handle_movement(_delta)->void:
	# Add the gravity.
	if not is_on_floor():
		velocity += get_gravity() * _delta
func handle_collisions()->void:
	for i in get_slide_collision_count():
		var c = get_slide_collision(i)
		if c.get_collider() is RigidBody2D:
			c.get_collider().apply_central_impulse(-c.get_normal()*BUMP_POWER)
		if c.get_collider() is NPCCharacter:
			var direction = -c.get_normal()*BUMP_POWER
			c.get_collider().knockBack(direction)			
func handle_update_states()->void:
	match current_player_state:
		PlayerState.IDLE when velocity.x !=0:
			current_player_state = PlayerState.RUNNING
		PlayerState.RUNNING when velocity.x ==0:
			current_player_state = PlayerState.IDLE
		PlayerState.JUMPING when velocity.y >0:
			current_player_state = PlayerState.FALLING
		PlayerState.FALLING when is_on_floor():
			if velocity.x == 0:
				current_player_state = PlayerState.IDLE
			else:
				current_player_state = PlayerState.RUNNING
func handle_update_animation()->void:
	match current_player_state:
		PlayerState.IDLE:
			player_graphic.play("idle")
		PlayerState.RUNNING:
			player_graphic.play("running")
		PlayerState.JUMPING:
			if upJump:
				player_graphic.play("jumping")
		PlayerState.FALLING:
			player_graphic.play("falling")


func _on_animation_finished() -> void:
	match current_player_state:
		PlayerState.JUMPING:
			upJump = false